**3.5. Банки**

Подсистема «Банки» предназначена для загрузки, хранения и предоставления другим подсистемам конфигурации классификатора банков. Загрузка классификатора может производиться как автоматически (при помощи регламентного задания с сайта 1С), так и вручную (с сайта 1С, с диска ИТС).

**Настройка**

Для использования подсистемы в конфигурации необходимо разместить в пользовательском интерфейсе ответственного за НСИ ссылку на справочник КлассификаторБанков.

**Настройка прав доступа пользователей**

Для настройки прав доступа пользователей к данным подсистемы «Банки» следует использовать роли, приведенные ниже.

Таблица 3.11.

|  |  |
| --- | --- |
| № | Роли и их назначение |
| 1. | БазовыеПраваБСП (из подсистемы «Базовая функциональность»)  Чтение записей классификатора банков РФ |
| 2. | ДобавлениеИзменениеБанков  Загрузка классификатора банков |
| 3. | ПолныеПрава, АдминистрированиеСистемы (из подсистемы «Базовая функциональность»)  Редактирование, удаление помеченных на удаление записей классификатора банков |

**Особые случаи внедрения подсистемы**

● [Внедрение подсистемы «Банки» без подсистемы «Контактная информация»](https://its.1c.ru/db/content/bsp301doc/src/3.63.%20особые%20случаи%20внедрения%20подсистем.htm?_=1542292879#_внедрение_подсистемы_«банки»).

**Использование при разработке конфигурации**

Данные классификатора банков РФ хранятся в справочнике КлассификаторБанковРФ. Данные о банках, измененные пользователем вручную, хранятся в справочниках банковских счетов. См. справочник \_ДемоБанковскиеСчета в демонстрационной конфигурации.

Для обращения к данным банковского счета при формировании печатной формы нужно применять следующий подход, проиллюстрированный на примере документа \_ДемоСчетНаОплатуПокупателю. Фрагмент текста запроса для выбора реквизитов банка:

[Копировать в буфер обмена](javascript:)

ВЫБОР

КОГДА БанковскийСчетКонтрагента.РучноеИзменениеРеквизитовБанка

ТОГДА БанковскийСчетКонтрагента.БИКБанка

ИНАЧЕ КлассификаторБанковРФ.Код

КОНЕЦ КАК БИКБанк,

ВЫБОР

КОГДА БанковскийСчетКонтрагента.РучноеИзменениеРеквизитовБанка

ТОГДА БанковскийСчетКонтрагента.НаименованиеБанка

ИНАЧЕ КлассификаторБанковРФ.Наименование

КОНЕЦ КАК НаименованиеБанка,

ВЫБОР

КОГДА БанковскийСчетКонтрагента.РучноеИзменениеРеквизитовБанка

ТОГДА БанковскийСчетКонтрагента.КоррСчетБанка

ИНАЧЕ КлассификаторБанковРФ.КоррСчет

КОНЕЦ КАК КоррСчетБанка,

ВЫБОР

КОГДА БанковскийСчетКонтрагента.РучноеИзменениеРеквизитовБанка

ТОГДА БанковскийСчетКонтрагента.ГородБанка

ИНАЧЕ КлассификаторБанковРФ.Город

КОНЕЦ КАК ГородБанка,

ВЫБОР

КОГДА БанковскийСчетКонтрагента.РучноеИзменениеРеквизитовБанкаДляРасчетов

ТОГДА БанковскийСчетКонтрагента.БИКБанкаДляРасчетов

ИНАЧЕ КлассификаторБанковКорреспондентовРФ.Код

КОНЕЦ КАК БИКБанкаДляРасчетов,

ВЫБОР

КОГДА БанковскийСчетКонтрагента.РучноеИзменениеРеквизитовБанкаДляРасчетов

ТОГДА БанковскийСчетКонтрагента.НаименованиеБанкаДляРасчетов

ИНАЧЕ КлассификаторБанковКорреспондентовРФ.Наименование

КОНЕЦ КАК НаименованиеБанкаДляРасчетов,

ВЫБОР

КОГДА БанковскийСчетКонтрагента.РучноеИзменениеРеквизитовБанкаДляРасчетов

ТОГДА БанковскийСчетКонтрагента.КоррСчетБанкаДляРасчетов

ИНАЧЕ КлассификаторБанковКорреспондентовРФ.КоррСчет

КОНЕЦ КАК КоррСчетБанкаДляРасчетов,

ВЫБОР

КОГДА БанковскийСчетКонтрагента.РучноеИзменениеРеквизитовБанкаДляРасчетов

ТОГДА БанковскийСчетКонтрагента.ГородБанкаДляРасчетов

ИНАЧЕ КлассификаторБанковКорреспондентовРФ.Город

КОНЕЦ КАК ГородБанкаДляРасчетов,

СчетНаОплатуПокупателю.Контрагент.НаименованиеПолное КАК ПолучательНаименованиеПолное,

БанковскийСчетКонтрагента.НомерСчета КАК ПолучательНомерСчета

ИЗ

Документ.\_ДемоСчетНаОплатуПокупателю КАК СчетНаОплатуПокупателю

ЛЕВОЕ СОЕДИНЕНИЕ Справочник.КлассификаторБанковРФ КАК КлассификаторБанковРФ

ПО СчетНаОплатуПокупателю.БанковскийСчет.Банк = КлассификаторБанковРФ.Ссылка

ЛЕВОЕ СОЕДИНЕНИЕ Справочник.КлассификаторБанковРФ КАК КлассификаторБанковКорреспондентовРФ

ПО СчетНаОплатуПокупателю.БанковскийСчет.БанкДляРасчетов = КлассификаторБанковКорреспондентовРФ.Ссылка

ЛЕВОЕ СОЕДИНЕНИЕ Справочник.\_ДемоБанковскиеСчета КАК БанковскийСчетКонтрагента

ПО СчетНаОплатуПокупателю.БанковскийСчет = БанковскийСчетКонтрагента

Пример кода по выводу реквизитов банка в табличный документ:

[Копировать в буфер обмена](javascript:)

ДанныеПечати = Новый Структура;

//...

Если ПустаяСтрока(Шапка.БИКБанкаДляРасчетов) Тогда

ДанныеПечати.Вставить("БанкПолучателяПредставление", СокрЛП(Шапка.НаименованиеБанка) + " " + СокрЛП(Шапка.ГородБанка));

ДанныеПечати.Вставить("ПредставлениеПоставщика", СокрЛП(Шапка.ПолучательНаименованиеПолное));

ДанныеПечати.Вставить("БИКБанкаПолучателя", СокрЛП(Шапка.БИКБанк));

ДанныеПечати.Вставить("СчетБанкаПолучателяПредставление", СокрЛП(Шапка.КоррСчетБанка));

ДанныеПечати.Вставить("СчетПолучателяПредставление", СокрЛП(Шапка.ПолучательНомерСчета));

Иначе

ДанныеПечати.Вставить("БанкПолучателяПредставление", СокрЛП(Шапка.НаименованиеБанкаДляРасчетов) + " " + СокрЛП(Шапка.ГородБанкаДляРасчетов));

ДанныеПечати.Вставить("ПредставлениеПоставщика", СокрЛП(Шапка.ПолучательНаименованиеПолное) + " р/с " + СокрЛП(Шапка.ПолучательНомерСчета) + " в " + СокрЛП(Шапка.НаименованиеБанка)+ " " + СокрЛП(Шапка.ГородБанка));

ДанныеПечати.Вставить("БИКБанкаПолучателя", СокрЛП(Шапка.БИКБанкаДляРасчетов));

ДанныеПечати.Вставить("СчетБанкаПолучателяПредставление", СокрЛП(Шапка.КоррСчетБанкаДляРасчетов));

ДанныеПечати.Вставить("СчетПолучателяПредставление", СокрЛП(Шапка.КоррСчетБанка));

КонецЕсли;

//...

Для Каждого ИмяОбласти Из МассивОбластейМакета Цикл

ОбластьМакета = Макет.ПолучитьОбласть(ИмяОбласти);

//...

ЗаполнитьЗначенияСвойств(ОбластьМакета.Параметры, ДанныеПечати);

ТабличныйДокумент.Вывести(ОбластьМакета);

//...

КонецЦикла;

Пример реализации печатной формы см. в демонстрационной конфигурации в документе \_ДемоСчетНаОплатуПокупателю.

**Настройка обмена данными**

Все объекты метаданных подсистемы, содержащие данные, кроме константы ИспользоватьАльтернативныйСерверДляЗагрузкиКлассификатораБанков, рекомендуется включать в планы обмена распределенной ИБ (РИБ).